home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Commodore Disc 2
/
Commodore_Disc_02_19xx_-_de.d64
/
kalorientab. 64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
15KB
|
469 lines
10 rem kalorientabelle ==========64
20 rem (p) 87 commodore welt team =
30 rem ============================
40 rem original by percy =
50 rem & egon kwapil =
60 rem =
70 rem version 2.0 40z/ascii =
80 rem c-64 + 1530/1541/1570/1571 =
90 rem ============================
100 x=42:gosub4190:printcl$:gosub220
110 poke53280,0:poke53281,0:poke53272,23
120 dimsp$(500),s$(500),d$(100)
130 rem ***************************
140 rem *************** umrandung *
150 rem ***************************
160 printtab(1);rd$rn$cd$kl$
170 printchr$(30);tab(14);cd$cd$cd$cd$"([195]) by [208]ercy"
180 printtab(14);cd$"[197]gon [203]wapil"
190 printtab(13);cd$"[195][207][205][205][207][196][207][210][197][160][215][197][204][212]"
200 fori=1to3000:next
210 goto340
220 forn=1024to1063:poken,x:next
230 forn=55296to55335:poken,6:next
240 forn=1063to2023step40:poken,x:next
250 forn=55335to56295step40:poken,6:next
260 forn=1984to2023:poken,x:next
270 forn=56256to56295:poken,6:next
280 forn=1984to1024step-40:poken,x:next
290 forn=56256to55296step-40:poken,6:next
300 fori=1to150:next:return
310 rem ***************************
320 rem ************ beschreibung *
330 rem ***************************
340 printks$
350 print" [205]it diesem [208]rogramm koennen [211]ie den"
360 print" [203]aloriengehalt und den [197]iweiss-"
370 print" gehalt den [198]ettgehalt und den"
380 print" [203]ohlenhydrategehalt verschiedener"
390 print" [211]peisen ermitteln."
400 print" [193]usserdem koennen sie nach [197]ingabe der"
410 print" [204]ebensmittlelmenge, die [211]ie zu [211]ich"
420 print" genommen haben, [201]hre persoenliche"
430 print" [193]uswertung abrufen."
440 print" [196]adurch wird es [201]hnen moeglich, [201]hre"
450 print" [197]rnaehrung in der [218]ukunft den"
460 print" benoetigten [205]engen anzupassen.":print:print
470 printwt$;we$:gosub4400
480 poke198,0:wait198,1
490 ifpeek(203)=14then1830
500 printks$
510 print" [202]eder zweite [194]undesbuerger, egal ob"
520 print" [215]eiblich oder [205]aennlich, moechte"
530 print" gern ein paaar [203]ilo leichter sein,"
540 print" aber trotzdem auf [199]enuss, [198]reude und"
550 print" [211]pass beim [197]ssen nicht verzichten"
560 print" [196]iese guten [214]orsaetze scheitern"
570 print" jedoch meisstens am [206]icht-[194]escheid-"
580 print" [215]issen ueber den [197]nergie- und [206]aehr-"
590 print" stoffgehalt der [206]ahrungsmittel."
600 print" [196]er [213]mgang mit diesem [208]rogramm soll"
610 print" [201]hnen nun dabei helfen."
620 print" [196]ie [215]erte sind portionsweise zu"
630 print" verstehen, das heisst pro [208]ortion,"
640 print" [211]tueck, [211]cheibe, [212]asse, [199]las,"
650 print" [197]ssloeffel oder [203]affeeloeffel.":print
660 printwt$;we$:gosub4400
670 poke198,0:wait198,1
680 ifpeek(203)=14 then1830
690 printks$
700 printye$" [215]as man ueber [203]alorien wissen sollte !"
710 printrd$" [203]ilokalorien ([203]cal) stammt von dem"
720 print" lateinischen [215]ort 'calor' und bedeutet"
730 print" [215]aerme. [197]ine [203]ilokalorie ([203]cal)"
740 print" ist diejenige [215]aermemenge, die"
750 print" notwendig ist um 1 [203]g [215]asser"
760 print" von 14.5 [195] auf 15.5 [195] zu erwaermen.":print:print
770 printwt$;we$
780 poke198,0:wait198,1
790 ifpeek(203)=14then1830
800 poke198,0:goto1830
810 rem ***************************
820 rem ************ dateneingabe *
830 rem ***************************
840 printks$
850 gosub4400:printcy$"[201]hr [193]lter"
860 x=4:y=20:gosub4490:l=2:z=1:r=1:gosub4500
870 al=val(e$):print:gosub4400
880 print"[201]hr [199]ewicht in [203]g.":x=6:y=20:gosub4490:l=3:z=1:r=2:gosub4500
890 kg=val(e$):ifal<10then1040
900 rem ***************************
910 rem ********* wertzuweisungen *
920 rem ***************************
930 ifkg<55thenkb=1600:goto1070
940 ifkg<60thenkb=1800:goto1070
950 ifkg<65thenkb=1950:goto1070
960 ifkg<70thenkb=2100:goto1070
970 ifkg<75thenkb=2250:goto1070
980 ifkg<80thenkb=2400:goto1070
990 ifkg<85thenkb=2600:goto1070
1000 ifkg<90thenkb=2750:goto1070
1010 ifkg<95thenkb=2900:goto1070
1020 ifkg<100thenkb=2900:goto1070
1030 ifkg>100thenkb=2500:goto1070
1040 ifal<4thenkb=kg*80:goto1070
1050 ifal<7thenkb=kg*75:goto1070
1060 ifal<10thenkb=kg*65
1070 eb=int(kg/0.9):hb=kg*5:print:fb=kg
1080 rem **************************
1090 rem ********* bedarfsausgabe *
1100 rem **************************
1110 printcd$cd$cd$cd$rd$"[201]hr [203]alorienbedarf =";kb;" [212]ag"cd$
1120 print"[201]hr [198]ettbedarf =";fb;"[199]ramm/[212]ag"cd$
1130 print"[201]hr [197]iweissbedarf =";eb;"[199]ramm/[212]ag"cd$
1140 print"[201]hr [203]ohl. [200]ydr. [194]ed. =";hb;"[199]ramm/[212]ag"cd$
1150 printcd$cd$cd$cd$wt$
1160 poke198,0:wait198,1:gosub4400:poke198,0
1170 goto2370
1180 rem **************************
1190 rem ******** directory lesen *
1200 rem **************************
1210 fori=0to100:d$(i)="":next
1220 printf1$s1$"[203]alorien-[201]naltsverzeichnis "cd$
1230 co=0
1240 printcy$;
1250 open1,8,0,"$0"
1260 get#1,a$,b$
1270 get#1,a$,b$
1280 get#1,a$,b$
1290 c=0
1300 ifa$<>""thenc=asc(a$)
1310 ifb$<>""thenc=c+asc(b$)*256
1320 get#1,b$:ifst<>0then1400
1330 ifb$<>chr$(47)then1320
1340 get#1,b$:ifb$<>chr$(34)thenprinttab(4);b$;:d$(co)=d$(co)+b$:goto1340
1350 get#1,b$:ifb$=chr$(32)then1350
1360 printtab(19);:c$=""
1370 c$=c$+b$:get#1,b$:ifb$<>""then1370
1380 printrd$left$(c$,3)
1390 ifst=0thenprintcy$;:co=co+1:goto1270
1400 print:close1
1410 close1:goto1420
1420 printwt$;we$
1430 poke198,0:wait198,1
1440 ifpeek(203)=14then4600
1450 poke198,0:goto1830
1460 ifq>1000thenfora=1to35:printfu$:next:goto1830
1470 rem **************************
1480 rem *********** dateneingabe *
1490 rem **************************
1500 printf1$s1$"[203]aloriendateneingabe"s2$cd$cd$
1510 printcd$cy$"[206]ame =>"cd$
1520 gosub4400:x=4:y=17:gosub4490:l=15:r=1:z=0:gosub4500
1530 sp$=e$
1540 printcd$cy$"kalorien =>"cd$
1550 gosub4400:x=6:y=17:gosub4490:l=3:r=1:z=1:gosub4500
1560 ka$=e$
1570 printcd$cy$"[197]iweiss =>"cd$
1580 gosub4400:x=8:y=17:gosub4490:l=3:r=1:z=1:gosub4500
1590 ew$=e$
1600 printcd$cy$"[198]ett =>"cd$
1610 gosub4400:x=10:y=17:gosub4490:l=3:r=1:z=1:gosub4500
1620 fe$=e$
1630 printcd$cy$"[203]ohlehydrate =>"cd$
1640 gosub4400:x=12:y=17:gosub4490:l=3:r=1:z=1:gosub4500
1650 kh$=e$
1660 gosub2900
1670 te$=left$(sp$+" ",15)+right$(" "+ka$,4)
1680 te$=te$+" "+right$(" "+ew$,3)
1690 te$=te$+" "+right$(" "+fe$,3)
1700 te$=te$+" "+right$(" "+kh$,3)
1710 te$=te$+" "+right$(" "+ar$,2)
1720 printcd$ye$rn$" [197]ingabe korrekt (j/n) "
1730 x=15:y=24:gosub4490:z=0:l=1:r=0:gosub4500
1740 a$=e$:ifa$="n"then1490
1750 ifa$="j"thenq=q+1:sp$(q)=te$:te$="":goto1770
1760 printcu$cu$cu$:goto1720
1770 printcu$cu$:printwt$we$:poke198,0:wait198,1
1780 ifpeek(203)=14then1830
1790 poke198,0:goto1460
1800 rem **************************
1810 rem ************* hauptmenue *
1820 rem **************************
1830 printf1$s1$"[203]alorientabelle"s2$cd$cd$
1840 printcd$cd$cy$"(1) [201]nhaltsverzeichnis"cd$
1850 print"(2) [203]alorien laden"cd$
1860 print"(3) [203]alorien speichern"cd$
1870 print"(4) [203]alorien eingeben"cd$
1880 print"(5) [203]alorien listen"cd$
1890 print"(6) [208]rogramm [197]nde"cd$cd$
1900 printgr$rn$"[201]hre [197]ingabe [194]itte"
1910 gosub4400:x=18:y=21:gosub4490:l=1:r=1:z=1:gosub4500
1920 ee=val(e$):if(ee<1)or(ee>6)then1830
1930 onval(e$)goto1220,2060,1940,1490,2250,4600
1940 rem **************************
1950 rem ***** kalorien speichern *
1960 rem **************************
1970 ifq<1then1830
1980 printf1$cd$s1$"[203]alorien [211]peichern"s2$cd$cd$
1990 printcd$cy$"[193]bspeichern unter"
2000 gosub4400:x=5:y=19:gosub4490:l=10:r=0:z=0:gosub4500
2010 ab$="@:kalo/"+e$+",s,w"
2020 open1,8,1,ab$
2030 print#1,str$(q);chr$(13);:printye$cd$cd$"[196]atenmenge = ";q
2040 forw=1toq:print#1,sp$(w);chr$(13);:next
2050 close1:goto1830
2060 rem **************************
2070 rem ********* kalorien laden *
2080 rem **************************
2090 printf1$cd$s1$"[203]alorien laden"s2$cd$cd$
2100 fori=0toco:printtab(4);d$(i):next
2110 clr:dimsp$(500),s$(500),d$(100):gosub4190
2120 printcd$cy$"[199]espeichert unter"cd$cd$
2130 gosub4400:x=peek(214)-3 :y=19:gosub4490:l=10:r=0:z=0:gosub4500
2140 se$=e$
2150 ab$="kalo/"+se$+",s,r"
2160 open1,8,0,ab$
2170 input#1,x$:q=val(x$):printye$cd$cd$"[196]atenmenge =";q
2180 ifq<1thenprintkd$:forkd=1to1500:next:goto2210
2190 forw=1toq:input#1,sp$(w):next
2200 ifb=1thenclose1:return
2210 close1:goto4010
2220 rem **************************
2230 rem *********** untermenue 1 *
2240 rem **************************
2250 printcl$rd$rn$"[203]alorientabelle"cd$cd$
2260 printcd$cd$cy$"(1) [203]alorien [193]uswerten"cd$
2270 print"(2) [203]alorien [211]ortieren "cd$
2280 print"(3) [203]alorien [193]uflisten"cd$
2290 print"(4) [197]nde"cd$
2300 printye$rn$"[201]hre [197]ingabe [194]itte"
2310 gosub4400:x=13:y=21:gosub4490:l=1:r=1:z=1:gosub4500
2320 ee=val(e$):if(ee<1)or(ee>4)then2250
2330 onval(e$)goto810,3190,4010,1830
2340 rem **************************
2350 rem ***** auswertungseingabe *
2360 rem **************************
2370 ifse$<>"tabelle"thense$="tabelle":b=1:gosub2150
2380 b=2:gosub2900:au=0:zk=1
2390 printcl$:ifar$="99"thengoto2680
2400 forau=1tow
2410 ifar$=mid$(sp$(au),33,1)then2430
2420 goto2460
2430 ifzk=1thenprintye$;au;tab(5);cy$;mid$(sp$(au),1,15);:zk=0:goto2460
2440 ifar$<>mid$(sp$(au),33,1)thenzk=0:goto2460
2450 ifzk=0thenprinttab(20);ye$;au;cy$;tab(25);mid$(sp$(au),1,14):zk=1
2460 next
2470 poke211,0
2480 printrn$ye$" [194]itte geben [211]ie die [206]ummer vor der "
2490 printrn$" [194]ezeichung was [211]ie gegessen oder "
2500 printrn$" getrunken haben ein . "
2510 gosub4400
2520 printcy$
2530 input"[206]ummer ";nr:printcu$;tab(20);:input"[193]nzahl ";az
2540 ka$=mid$(sp$(nr),17,3):ka=val(ka$)
2550 ei$=mid$(sp$(nr),21,3):ei=val(ei$)
2560 fe$=mid$(sp$(nr),25,3):fe=val(fe$)
2570 ko$=mid$(sp$(nr),29,3):ko=val(ko$)
2580 kv=kv+ka*az:ev=ev+ei*az
2590 fv=fv+fe*az:hv=hv+ko*az
2600 gosub4400:printye$cu$
2610 input"[215]eitere [193]rten = 1, [193]nderes [199]ebiet = 2";xx
2620 ifxx=2thengoto2380
2630 printcu$cu$" "
2640 printcu$cu$;spc(39);cu$:goto2510
2650 rem **************************
2660 rem ***** auswertungsausgabe *
2670 rem **************************
2680 printf1$kl$cd$ye$
2690 print"[201]hr [203]alorienbedarf =";kb;"[212]ag"
2700 print"[203]alorienverbrauch =";kv
2710 print"[196]ifferenz =";:di=kb-kv:printdi:print
2720 print"[201]hr [198]ettbegarf =";fb;"[199]ramm/[212]ag"
2730 print"[198]ettverbrauch =";fv
2740 print"[196]ifferenz =";:di=fb-fv:printdi:print
2750 print"[201]hr [203]ohl.[200]yd.[194]edarf=";hb;" [199]ramm/[212]ag"
2760 print"[203]ohl.[200]ydr.[214]erbr. =";hv
2770 print"[196]ifferenz =";:di=hb-hv:printdi:print
2780 print"[201]hr [197]iweissbedarf =";eb;" [199]ramm/[212]ag"
2790 print"[197]iweissverbrauch =";ev
2800 print"[196]ifferenz =";:di=eb-ev:printdi:print
2810 gosub4400
2820 printrn$"[193]nfang = 1, [197]nde = 2 "
2830 x=18:y=23:gosub4490:l=1:z=1:r=1:gosub4500
2840 xx=val(e$)
2850 ifxx=2goto4370
2860 kv=0:ev=0:hv=0:fv=0:goto1830
2870 rem **************************
2880 rem ********* eingabeauswahl *
2890 rem **************************
2900 printf1$s1$"[197]ingabe [193]uswahl"s2$cd$cd$
2910 ifb=2thenprintf1$kl$cd$cd$
2920 printcy$"[199]etraenke = 1 ";
2930 print"[194]rotarten = 2"
2940 print"[193]ufstrich = 3 ";
2950 print"[211]uppen = 4"
2960 print"[198]leisch = 5 ";
2970 print"[198]isch = 6"
2980 print"[199]efluegel = 7 ";
2990 print"[194]eilagen = 8"
3000 print"[199]emuese-[207]bst = 9 ";
3010 print"[211]aucen = [193]"
3020 print"[197]ierspeisen = [194] ";
3030 print"[206]achtisch = [195]"
3040 print"[215]urst = [196] ";
3050 print"[199]ebaeck = [197]"
3060 print"[203]aese = [198] ";
3070 print"[203]uchen = [199]"
3080 print"[211]uessigkeiten = [200] ";
3090 ifb=2thenprint"[197]nde =99"
3100 ifb=2thenprintcd$ye$"[201]hre [215]ahl [194]itte =>"cd$:goto3120
3110 printcd$cd$ye$" [193]rt [194]itte =>"cd$
3120 gosub4400:x=13:y=19:gosub4490:l=2:r=0:z=0:gosub4500
3130 ar$=e$:ifar$="99"then2680
3140 ifar$=""then2760
3150 return
3160 rem **************************
3170 rem *********** untermenue 2 *
3180 rem **************************
3190 printf1$s1$"[203]alorien-[211]ort"s2$cd$cd$
3200 printcd$cd$cy$"(1) [211]ort [193]-[218]"cd$
3210 print"(2) [211]ort nach [203]alorien"cd$
3220 print"(3) [211]ort nach [197]iweiss"cd$
3230 print"(4) [211]ort nach [198]ett"cd$
3240 print"(5) [211]ort nach [203]oh.[200]ydr."cd$
3250 print"(6) [197]nde"cd$
3260 printye$rn$"[201]hre [197]ingabe [194]itte"
3270 gosub4400:x=17:y=21:gosub4490:l=1:r=1:z=1:gosub4500
3280 ee=val(e$):if(ee<1)or(ee>6)then3190
3290 onval(e$)goto3330,3690,3770,3820,3930,2250
3300 rem **************************
3310 rem ********* sortierroutine *
3320 rem **************************
3330 printf1$s1$"[203]alorien-[211]ort"s2$cd$
3340 forn=1to500:next
3350 l=int(q/2)+1:ifq=0thenprintkv$:forpp=1to1500:next:goto1830
3360 r=q:printho$rd$cd$cd$cd$cd$cd$"[206]r. ";right$(" "+str$(abs(r)),3)
3370 ifl>1then3440
3380 ifr<=1then3430
3390 h$=sp$(l)
3400 sp$(l)=sp$(r)
3410 sp$(r)=h$
3420 r=r-1
3430 goto3450
3440 l=l-1
3450 j=l
3460 i=2*j
3470 h$=sp$(j)
3480 ifi>rthen3600
3490 ifi>=rthen3540
3500 ifsp$(i)>=sp$(i+1)then3540
3510 i=i+1
3520 printho$ye$cd$cd$cd$cd$cd$;
3530 print"[206]r. ";right$(" "+str$(i),3):printcd$cy$;sp$(i)
3540 ifi>rthen3600
3550 ifh$>=sp$(i)then3600
3560 sp$(j)=sp$(i)
3570 j=i
3580 i=2*j
3590 goto3490
3600 sp$(j)=h$
3610 ifr<>1then3370
3620 ifb=1thenreturn
3630 goto2250
3640 rem **************************
3650 rem ** $ aufteilen fuer sort *
3660 rem **************************
3670 rem ***** kalorienaufteilung *
3680 rem **************************
3690 b=1:e$=se$:gosub2150
3700 fort=1tow:s$(w)=mid$(sp$(t),17,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
3710 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
3720 fort=1tow:s$(w)=mid$(sp$(t),5,16)+mid$(sp$(t),1,4)
3730 sp$(t)=s$(w):next:b=0:goto2250
3740 rem **************************
3750 rem ****** eiweissaufteilung *
3760 rem **************************
3770 b=1:e$=se$:gosub2150
3780 fort=1tow:s$(w)=mid$(sp$(t),21,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
3790 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
3800 fort=1tow:s$(w)=mid$(sp$(t),4,16)+" "+mid$(sp$(t),1,4)
3810 sp$(t)=s$(w):next:b=0:goto2250
3820 b=1:e$=se$:gosub2150
3830 rem **************************
3840 rem ********* fettaufteilung *
3850 rem **************************
3860 fort=1tow:s$(w)=mid$(sp$(t),25,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
3870 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
3880 fort=1tow:s$(w)=mid$(sp$(t),4,16)+" "+mid$(sp$(t),1,4)
3890 sp$(t)=s$(w):next:b=0:goto2250
3900 rem **************************
3910 rem ****** hydrateaufteilung *
3920 rem **************************
3930 b=1:e$=se$:gosub2150
3940 fort=1tow:s$(w)=mid$(sp$(t),29,3):s$(w)=s$(w)+" "+mid$(sp$(t),1,16)
3950 sp$(t)=s$(w):next:sp$(w)=sp$(t):b=1:gosub3330
3960 fort=1tow:s$(w)=mid$(sp$(t),5,16)+" "+mid$(sp$(t),1,4)
3970 sp$(t)=s$(w):next:b=0:goto2250
3980 rem **************************
3990 rem ************* auflistung *
4000 rem **************************
4010 printf1$s1$"[193]uflistung"s2$s2$
4020 zz=0
4030 printye$" [211]peise [203]. [197]i. [198]t. [203]h. [193]rt "
4040 ifq=0thenprintkv$:forkv=1to1500:next:goto1830
4050 forl=1toq:ifl+x1>1000thenx1=0:goto1830
4060 printro$;right$(" "+str$(l+x1),3);" ";:zz=zz+1
4070 printcy$;sp$(l+x1);ro$:ifzz=15thenzz=0:goto4090
4080 goto4120
4090 print:printwt$;we$:poke198,0:wait198,1
4100 ifpeek(203)=14thenx1=0:poke198,0:goto1830
4110 printcl$ye$" [211]peise [203]. [197]i. [198]t. [203]h. [193]rt "
4120 next
4130 print:printwt$;we$:poke198,0:wait198,1
4140 ifpeek(203)=14thenx1=0:poke198,0: goto1830
4150 poke198,0:goto1830
4160 rem **************************
4170 rem ****** stringzuweisungen *
4180 rem **************************
4190 cd$=chr$(017):cu$=chr$(145)
4200 ch$=chr$(029):ct$=chr$(157)
4210 rn$=chr$(018):rf$=chr$(146)
4220 ho$=chr$(019):cl$=chr$(147)
4230 rd$=chr$(028):gr$=chr$(030):de$=ct$+" "+ct$+ct$
4240 cy$=chr$(159):ro$=chr$(031):ws$=chr$(5):bl$=chr$(175)
4250 kl$=" [203]alorienauswertung "
4260 ks$=cl$+cd$+cd$+rd$+rn$+" "+kl$+" "+cd$
4270 f1$=cl$+rd$+rn$
4280 wt$=gr$+rn$+" [215]eiter mit [211]pace "
4290 we$=gr$+rn$+" [197][206][196][197] = [[197]] "
4300 s1$=" ":s2$=" "
4310 cp$=cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$+cd$
4320 fu$=cl$+ye$+rn$+cp$+s1$+"[211] [208] [197] [201] [195] [200] [197] [210] [214] [207] [204] [204]"+s1$
4330 kd$=cl$+ye$+rn$+cp$+"[203]eine [196]atei unter diesem [206]amen vorhanden"
4340 c$(1)=ws$+bl$+ct$+cy$:c$(2)=rd$+bl$+ct$+cy$
4350 kv$=cl$+ye$+rn$+cp$+" [203]eine [196]aten vorhanden! "
4360 return
4370 rem **************************
4380 rem ************ ton-routine *
4390 rem **************************
4400 si=54272
4410 pokesi+24,15:pokesi+7,240:pokesi+8,10:pokesi+13,11
4420 pokesi+24,15:pokesi+0,111:pokesi+1,34:pokesi+6,13
4430 pokesi+11,17:pokesi+4,16
4440 pokesi+4,17:pokesi+4,16
4450 return
4460 rem **************************
4470 rem ************ get-routine *
4480 rem **************************
4490 printho$;:forxx=1tox:print:next:printspc(y):fori=1to150:next:return
4500 e$="":x=1
4510 printc$(x);:y=y+1:ify>10theny=1:x=x+1:ifx>2thenx=1
4520 gety$:ify$=""goto4510
4530 y=asc(y$):ify=13andlen(e$)>r-1thenprint" ":return
4540 ify$=chr$(20)andlen(e$)>0thene$=left$(e$,len(e$)-1):printde$;:goto4520
4550 ifz=0thenify<32ory>127andy<160goto4520
4560 ifz=1thenify<32ory>32thenify<46ory>57goto4520
4570 iflen(e$)>l-1goto4510
4580 e$=e$+y$:printy$;:goto4510
4590 r=1:l=8:n=0:gosub4490
4600 poke198,0:poke53272,21:printcl$:end
4610 rem kalorientabelle ========64
4620 rem 38911 bytes memory ====
4630 rem 14522 bytes program ====
4640 rem 00266 bytes variables ====
4650 rem 03370 bytes arrays ====
4660 rem 00657 bytes strings ====
4670 rem 20096 bytes free (0) ====
4680 rem ==========================